Competency Questions

Several designed competency questions are presented below, alongside their related SPARQL queries and outputs. These competency questions aim at demonstrating the usefulness of EducOnto for a wide range of operational tasks.

CQ1: How to retrieve recommended/required academic backgrounds for a specific curriculum?

CQ1 aims at checking what academic backgrounds are recommended or even required for a specific curriculum. This is because there exist many structural restrictions in the educational system. For instance, a high school senior who is majoring in Literature will be denied access to most scientific curricula.

PREFIX ed: <http://purl.org/educonto/>
PREFIX major: <http://purl.org/edukg/major/>
PREFIX curriculum: <http://purl.org/edukg/curriculum/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?major 
WHERE {
    ?major rdf:type/rdfs:subClassOf* ed:HighSchoolMajor.
    curriculum:lg_cs ed:recommendsHighSchoolMajor ?major .
}

CQ2: What is the most popular higher education curriculum for students coming from a given high school major?

CQ2 seeks to retrieve the most picked-up curricula by students sharing the same high school major as the active user. This consideration is of major importance as some high school majors allow access to a large number of higher education curricula. In such circumstances, retrieving all the accessible curricula given a high school major may result in a vast amount of choices and the student would still feel overwhelmed.

PREFIX ed: <http://purl.org/educonto/>
PREFIX major: <http://purl.org/edukg/major/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?curriculum (COUNT(?curriculum) AS ?count)
WHERE
{ ?student rdf:type ed:UndergraduateStudent .
  ?student ed:likedCurriculum ?curriculum .
  ?student ed:pickedGeneralMajor major:ts .
}
GROUP BY ?curriculum
ORDER BY DESC(?count)
LIMIT 5

CQ3: How to personalize curricula recommendations based on a student's profile?

CQ3 evaluates the ability of our ontology to return curricula that match student’s personality and preferences. In the query presented below, keywords that the active student mentioned are considered as insightful preferences to focus on.

PREFIX ed: <http://purl.org/educonto/>
PREFIX student: <http://purl.org/edukg/stud/>

SELECT ?curriculum (COUNT(?keyword) AS ?commonKeywords)
WHERE {
    student:user3037 ed:isInterestedInKeyword ?keyword .
    ?curriculum ed:curriculumRelatesToKeyword ?keyword .
}
GROUP BY ?curriculum
ORDER BY DESC(?commonKeywords)

CQ4: Based on some initial curriculum a high school senior is interested in, what are the alternative curricula he might also consider?

CQ4 aims at leveraging relationships between the total set of curricula and the ones the active student is explicitly interested in. CQ4 is a broad question that can be answered in many ways. Consequently, it is further subdivided below for improved clarity.

CQ4.1: What are the alternative curricula regarding the curriculum's class?

CQ4.1 regards the curriculum's type as the main criterion for retrieving similar curricula.

PREFIX ed: <http://purl.org/educonto/>
PREFIX student: <http://purl.org/edukg/stud/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?alternative
WHERE {
    student:user351 ed:mentionedCurriculum ?curriculum .
    ?curriculum rdf:type ?type .
    ?alternative rdf:type ?type .
    FILTER(?curriculum != ?alternative) .
}

CQ4.2: What are the curricula sharing the same keywords?

CQ4.2 regards the shared keywords as the main criterion for retrieving similar curricula.

PREFIX ed: <http://purl.org/educonto/>
PREFIX student: <http://purl.org/edukg/stud/>

SELECT ?alternative (COUNT(?keyword) AS ?commonKeywords)
WHERE {
    student:user351 ed:mentionedCurriculum ?curriculum .
    ?curriculum ed:curriculumRelatesToKeyword ?keyword .
    ?alternative ed:curriculumRelatesToKeyword ?keyword .
    FILTER(?curriculum != ?alternative) .
}
GROUP BY ?alternative
ORDER BY DESC(?commonKeywords)

CQ4.3: What are the curricula related to the same field of study?

CQ4.3 regards the field of study as the main criterion for retrieving similar curricula.

PREFIX ed: <http://purl.org/educonto/>
PREFIX student: <http://purl.org/edukg/stud/>

SELECT ?alternative
WHERE {
    student:user351 ed:mentionedCurriculum ?curriculum .
    ?curriculum ed:belongsToFieldOfStudy ?field .
    ?alternative ed:belongsToFieldOfStudy ?field .
    FILTER(?curriculum != ?alternative) .
}
GROUP BY ?alternative

CQ5: How to mine the most influential factors leading to a particular curricula?

CQ5 is motivated by a higher-level viewpoint. It asks what are the recurrent features of students following a given curriculum.

PREFIX ed: <http://purl.org/educonto/>
PREFIX curriculum: <http://purl.org/edukg/curriculum/>

SELECT ?keywordOrSubject ?preferredKeywordOrSubject
WHERE
{ 
	{
        SELECT (?subject AS ?keywordOrSubject) (COUNT(?subject) AS ?preferredKeywordOrSubject) WHERE 
        {
   			?student ed:likedCurriculum curriculum:cpge_mpsi .
    		?student ed:hasFavoriteSchoolSubject ?subject .
        }
        GROUP BY ?subject
    }
UNION
	{
        SELECT (?keyword AS ?keywordOrSubject) (COUNT(?keyword) AS ?preferredKeywordOrSubject) WHERE 
        {
    		?student ed:likedCurriculum curriculum:cpge_mpsi .
    		?student ed:isInterestedInKeyword ?keyword .
		}
        GROUP BY ?keyword
	}
}
GROUP BY ?keywordOrSubject ?preferredKeywordOrSubject
ORDER BY DESC(?preferredKeywordOrSubject)
LIMIT 15